332 lines
15 KiB
LLVM
332 lines
15 KiB
LLVM
; RUN: opt < %s -wasm-lower-em-ehsjlj -S | FileCheck %s --check-prefixes=CHECK,NO-TLS
|
|
; RUN: opt < %s -wasm-lower-em-ehsjlj -S --mattr=+atomics,+bulk-memory | FileCheck %s --check-prefixes=CHECK,TLS
|
|
|
|
target datalayout = "e-m:e-p:32:32-i64:64-n32:64-S128"
|
|
target triple = "wasm32-unknown-unknown"
|
|
|
|
%struct.__jmp_buf_tag = type { [6 x i32], i32, [32 x i32] }
|
|
|
|
@global_var = global i32 0, align 4
|
|
; NO-TLS-DAG: __THREW__ = external global i32
|
|
; NO-TLS-DAG: __threwValue = external global i32
|
|
; TLS-DAG: __THREW__ = external thread_local(localexec) global i32
|
|
; TLS-DAG: __threwValue = external thread_local(localexec) global i32
|
|
@global_longjmp_ptr = global void (%struct.__jmp_buf_tag*, i32)* @longjmp, align 4
|
|
; CHECK-DAG: @global_longjmp_ptr = global void (%struct.__jmp_buf_tag*, i32)* bitcast (void (i32, i32)* @emscripten_longjmp to void (%struct.__jmp_buf_tag*, i32)*)
|
|
|
|
; Test a simple setjmp - longjmp sequence
|
|
define void @setjmp_longjmp() {
|
|
; CHECK-LABEL: @setjmp_longjmp
|
|
entry:
|
|
%buf = alloca [1 x %struct.__jmp_buf_tag], align 16
|
|
%arraydecay = getelementptr inbounds [1 x %struct.__jmp_buf_tag], [1 x %struct.__jmp_buf_tag]* %buf, i32 0, i32 0
|
|
%call = call i32 @setjmp(%struct.__jmp_buf_tag* %arraydecay) #0
|
|
%arraydecay1 = getelementptr inbounds [1 x %struct.__jmp_buf_tag], [1 x %struct.__jmp_buf_tag]* %buf, i32 0, i32 0
|
|
call void @longjmp(%struct.__jmp_buf_tag* %arraydecay1, i32 1) #1
|
|
unreachable
|
|
; CHECK: entry:
|
|
; CHECK-NEXT: %[[MALLOCCALL:.*]] = tail call i8* @malloc(i32 40)
|
|
; CHECK-NEXT: %[[SETJMP_TABLE:.*]] = bitcast i8* %[[MALLOCCALL]] to i32*
|
|
; CHECK-NEXT: store i32 0, i32* %[[SETJMP_TABLE]]
|
|
; CHECK-NEXT: %[[SETJMP_TABLE_SIZE:.*]] = add i32 4, 0
|
|
; CHECK-NEXT: %[[BUF:.*]] = alloca [1 x %struct.__jmp_buf_tag]
|
|
; CHECK-NEXT: %[[ARRAYDECAY:.*]] = getelementptr inbounds [1 x %struct.__jmp_buf_tag], [1 x %struct.__jmp_buf_tag]* %[[BUF]], i32 0, i32 0
|
|
; CHECK-NEXT: %[[SETJMP_TABLE1:.*]] = call i32* @saveSetjmp(%struct.__jmp_buf_tag* %[[ARRAYDECAY]], i32 1, i32* %[[SETJMP_TABLE]], i32 %[[SETJMP_TABLE_SIZE]])
|
|
; CHECK-NEXT: %[[SETJMP_TABLE_SIZE1:.*]] = call i32 @getTempRet0()
|
|
; CHECK-NEXT: br label %entry.split
|
|
|
|
; CHECK: entry.split:
|
|
; CHECK-NEXT: phi i32 [ 0, %entry ], [ %[[LONGJMP_RESULT:.*]], %if.end ]
|
|
; CHECK-NEXT: %[[ARRAYDECAY1:.*]] = getelementptr inbounds [1 x %struct.__jmp_buf_tag], [1 x %struct.__jmp_buf_tag]* %[[BUF]], i32 0, i32 0
|
|
; CHECK-NEXT: %[[JMPBUF:.*]] = ptrtoint %struct.__jmp_buf_tag* %[[ARRAYDECAY1]] to i32
|
|
; CHECK-NEXT: store i32 0, i32* @__THREW__
|
|
; CHECK-NEXT: call cc{{.*}} void @__invoke_void_i32_i32(void (i32, i32)* @emscripten_longjmp, i32 %[[JMPBUF]], i32 1)
|
|
; CHECK-NEXT: %[[__THREW__VAL:.*]] = load i32, i32* @__THREW__
|
|
; CHECK-NEXT: store i32 0, i32* @__THREW__
|
|
; CHECK-NEXT: %[[CMP0:.*]] = icmp ne i32 %__THREW__.val, 0
|
|
; CHECK-NEXT: %[[THREWVALUE_VAL:.*]] = load i32, i32* @__threwValue
|
|
; CHECK-NEXT: %[[CMP1:.*]] = icmp ne i32 %[[THREWVALUE_VAL]], 0
|
|
; CHECK-NEXT: %[[CMP:.*]] = and i1 %[[CMP0]], %[[CMP1]]
|
|
; CHECK-NEXT: br i1 %[[CMP]], label %if.then1, label %if.else1
|
|
|
|
; CHECK: entry.split.split:
|
|
; CHECK-NEXT: unreachable
|
|
|
|
; CHECK: if.then1:
|
|
; CHECK-NEXT: %[[__THREW__VAL_I32P:.*]] = inttoptr i32 %[[__THREW__VAL]] to i32*
|
|
; CHECK-NEXT: %[[__THREW__VAL_I32P_LOADED:.*]] = load i32, i32* %[[__THREW__VAL_I32P]]
|
|
; CHECK-NEXT: %[[LABEL:.*]] = call i32 @testSetjmp(i32 %[[__THREW__VAL_I32P_LOADED]], i32* %[[SETJMP_TABLE1]], i32 %[[SETJMP_TABLE_SIZE1]])
|
|
; CHECK-NEXT: %[[CMP:.*]] = icmp eq i32 %[[LABEL]], 0
|
|
; CHECK-NEXT: br i1 %[[CMP]], label %if.then2, label %if.end2
|
|
|
|
; CHECK: if.else1:
|
|
; CHECK-NEXT: br label %if.end
|
|
|
|
; CHECK: if.end:
|
|
; CHECK-NEXT: %[[LABEL_PHI:.*]] = phi i32 [ %[[LABEL:.*]], %if.end2 ], [ -1, %if.else1 ]
|
|
; CHECK-NEXT: %[[LONGJMP_RESULT]] = call i32 @getTempRet0()
|
|
; CHECK-NEXT: switch i32 %[[LABEL_PHI]], label %entry.split.split [
|
|
; CHECK-NEXT: i32 1, label %entry.split
|
|
; CHECK-NEXT: ]
|
|
|
|
; CHECK: if.then2:
|
|
; CHECK-NEXT: call void @emscripten_longjmp(i32 %[[__THREW__VAL]], i32 %[[THREWVALUE_VAL]])
|
|
; CHECK-NEXT: unreachable
|
|
|
|
; CHECK: if.end2:
|
|
; CHECK-NEXT: call void @setTempRet0(i32 %[[THREWVALUE_VAL]])
|
|
; CHECK-NEXT: br label %if.end
|
|
}
|
|
|
|
; Test a case of a function call (which is not longjmp) after a setjmp
|
|
define void @setjmp_other() {
|
|
; CHECK-LABEL: @setjmp_other
|
|
entry:
|
|
%buf = alloca [1 x %struct.__jmp_buf_tag], align 16
|
|
%arraydecay = getelementptr inbounds [1 x %struct.__jmp_buf_tag], [1 x %struct.__jmp_buf_tag]* %buf, i32 0, i32 0
|
|
%call = call i32 @setjmp(%struct.__jmp_buf_tag* %arraydecay) #0
|
|
call void @foo()
|
|
ret void
|
|
; CHECK: entry:
|
|
; CHECK: %[[SETJMP_TABLE:.*]] = call i32* @saveSetjmp(
|
|
|
|
; CHECK: entry.split:
|
|
; CHECK: @__invoke_void(void ()* @foo)
|
|
|
|
; CHECK: entry.split.split:
|
|
; CHECK-NEXT: %[[BUF:.*]] = bitcast i32* %[[SETJMP_TABLE]] to i8*
|
|
; CHECK-NEXT: tail call void @free(i8* %[[BUF]])
|
|
; CHECK-NEXT: ret void
|
|
}
|
|
|
|
; Test a case when a function call is within try-catch, after a setjmp
|
|
define void @exception_and_longjmp() personality i8* bitcast (i32 (...)* @__gxx_personality_v0 to i8*) {
|
|
; CHECK-LABEL: @exception_and_longjmp
|
|
entry:
|
|
%buf = alloca [1 x %struct.__jmp_buf_tag], align 16
|
|
%arraydecay = getelementptr inbounds [1 x %struct.__jmp_buf_tag], [1 x %struct.__jmp_buf_tag]* %buf, i32 0, i32 0
|
|
%call = call i32 @setjmp(%struct.__jmp_buf_tag* %arraydecay) #0
|
|
invoke void @foo()
|
|
to label %try.cont unwind label %lpad
|
|
|
|
; CHECK: entry.split:
|
|
; CHECK: store i32 0, i32* @__THREW__
|
|
; CHECK-NEXT: call cc{{.*}} void @__invoke_void(void ()* @foo)
|
|
; CHECK-NEXT: %[[__THREW__VAL:.*]] = load i32, i32* @__THREW__
|
|
; CHECK-NEXT: store i32 0, i32* @__THREW__
|
|
; CHECK-NEXT: %[[CMP0:.*]] = icmp ne i32 %[[__THREW__VAL]], 0
|
|
; CHECK-NEXT: %[[THREWVALUE_VAL:.*]] = load i32, i32* @__threwValue
|
|
; CHECK-NEXT: %[[CMP1:.*]] = icmp ne i32 %[[THREWVALUE_VAL]], 0
|
|
; CHECK-NEXT: %[[CMP:.*]] = and i1 %[[CMP0]], %[[CMP1]]
|
|
; CHECK-NEXT: br i1 %[[CMP]], label %if.then1, label %if.else1
|
|
|
|
; CHECK: entry.split.split:
|
|
; CHECK-NEXT: %[[CMP:.*]] = icmp eq i32 %[[__THREW__VAL]], 1
|
|
; CHECK-NEXT: br i1 %[[CMP]], label %lpad, label %try.cont
|
|
|
|
lpad: ; preds = %entry
|
|
%0 = landingpad { i8*, i32 }
|
|
catch i8* null
|
|
%1 = extractvalue { i8*, i32 } %0, 0
|
|
%2 = extractvalue { i8*, i32 } %0, 1
|
|
%3 = call i8* @__cxa_begin_catch(i8* %1) #2
|
|
call void @__cxa_end_catch()
|
|
br label %try.cont
|
|
|
|
try.cont: ; preds = %entry, %lpad
|
|
ret void
|
|
}
|
|
|
|
; Test SSA validity
|
|
define void @ssa(i32 %n) {
|
|
; CHECK-LABEL: @ssa
|
|
entry:
|
|
%buf = alloca [1 x %struct.__jmp_buf_tag], align 16
|
|
%cmp = icmp sgt i32 %n, 5
|
|
br i1 %cmp, label %if.then, label %if.end
|
|
; CHECK: entry:
|
|
; CHECK: %[[SETJMP_TABLE0:.*]] = bitcast i8*
|
|
; CHECK: %[[SETJMP_TABLE_SIZE0:.*]] = add i32 4, 0
|
|
|
|
if.then: ; preds = %entry
|
|
%0 = load i32, i32* @global_var, align 4
|
|
%arraydecay = getelementptr inbounds [1 x %struct.__jmp_buf_tag], [1 x %struct.__jmp_buf_tag]* %buf, i32 0, i32 0
|
|
%call = call i32 @setjmp(%struct.__jmp_buf_tag* %arraydecay) #0
|
|
store i32 %0, i32* @global_var, align 4
|
|
br label %if.end
|
|
; CHECK: if.then:
|
|
; CHECK: %[[VAR0:.*]] = load i32, i32* @global_var, align 4
|
|
; CHECK: %[[SETJMP_TABLE1:.*]] = call i32* @saveSetjmp(
|
|
; CHECK-NEXT: %[[SETJMP_TABLE_SIZE1:.*]] = call i32 @getTempRet0()
|
|
|
|
; CHECK: if.then.split:
|
|
; CHECK: %[[VAR1:.*]] = phi i32 [ %[[VAR0]], %if.then ], [ %[[VAR2:.*]], %if.end3 ]
|
|
; CHECK: %[[SETJMP_TABLE_SIZE2:.*]] = phi i32 [ %[[SETJMP_TABLE_SIZE1]], %if.then ], [ %[[SETJMP_TABLE_SIZE3:.*]], %if.end3 ]
|
|
; CHECK: %[[SETJMP_TABLE2:.*]] = phi i32* [ %[[SETJMP_TABLE1]], %if.then ], [ %[[SETJMP_TABLE3:.*]], %if.end3 ]
|
|
; CHECK: store i32 %[[VAR1]], i32* @global_var, align 4
|
|
|
|
if.end: ; preds = %if.then, %entry
|
|
%arraydecay1 = getelementptr inbounds [1 x %struct.__jmp_buf_tag], [1 x %struct.__jmp_buf_tag]* %buf, i32 0, i32 0
|
|
call void @longjmp(%struct.__jmp_buf_tag* %arraydecay1, i32 5) #1
|
|
unreachable
|
|
; CHECK: if.end:
|
|
; CHECK: %[[VAR2]] = phi i32 [ %[[VAR1]], %if.then.split ], [ undef, %entry ]
|
|
; CHECK: %[[SETJMP_TABLE_SIZE3]] = phi i32 [ %[[SETJMP_TABLE_SIZE2]], %if.then.split ], [ %[[SETJMP_TABLE_SIZE0]], %entry ]
|
|
; CHECK: %[[SETJMP_TABLE3]] = phi i32* [ %[[SETJMP_TABLE2]], %if.then.split ], [ %[[SETJMP_TABLE0]], %entry ]
|
|
}
|
|
|
|
; Test a case when a function only calls other functions that are neither setjmp nor longjmp
|
|
define void @only_other_func() {
|
|
entry:
|
|
call void @foo()
|
|
ret void
|
|
; CHECK: call void @foo()
|
|
}
|
|
|
|
; Test a case when a function only calls longjmp and not setjmp
|
|
define void @only_longjmp() {
|
|
entry:
|
|
%buf = alloca [1 x %struct.__jmp_buf_tag], align 16
|
|
%arraydecay = getelementptr inbounds [1 x %struct.__jmp_buf_tag], [1 x %struct.__jmp_buf_tag]* %buf, i32 0, i32 0
|
|
call void @longjmp(%struct.__jmp_buf_tag* %arraydecay, i32 5) #1
|
|
unreachable
|
|
; CHECK: %[[JMPBUF:.*]] = ptrtoint
|
|
; CHECK-NEXT: call void @emscripten_longjmp(i32 %[[JMPBUF]], i32 5)
|
|
}
|
|
|
|
; Test inline asm handling
|
|
define void @inline_asm() {
|
|
; CHECK-LABEL: @inline_asm
|
|
entry:
|
|
%env = alloca [1 x %struct.__jmp_buf_tag], align 16
|
|
%arraydecay = getelementptr inbounds [1 x %struct.__jmp_buf_tag], [1 x %struct.__jmp_buf_tag]* %env, i32 0, i32 0
|
|
%call = call i32 @setjmp(%struct.__jmp_buf_tag* %arraydecay) #4
|
|
; Inline assembly should not generate __invoke wrappers.
|
|
; Doing so would fail as inline assembly cannot be passed as a function pointer.
|
|
; CHECK: call void asm sideeffect "", ""()
|
|
; CHECK-NOT: __invoke_void
|
|
call void asm sideeffect "", ""()
|
|
ret void
|
|
}
|
|
|
|
; Test that the allocsize attribute is being transformed properly
|
|
declare i8 *@allocator(i32, %struct.__jmp_buf_tag*) #3
|
|
define i8 *@allocsize() {
|
|
; CHECK-LABEL: @allocsize
|
|
entry:
|
|
%buf = alloca [1 x %struct.__jmp_buf_tag], align 16
|
|
%arraydecay = getelementptr inbounds [1 x %struct.__jmp_buf_tag], [1 x %struct.__jmp_buf_tag]* %buf, i32 0, i32 0
|
|
%call = call i32 @setjmp(%struct.__jmp_buf_tag* %arraydecay) #0
|
|
; CHECK: call cc{{.*}} i8* @"__invoke_i8*_i32_%struct.__jmp_buf_tag*"([[ARGS:.*]]) #[[ALLOCSIZE_ATTR:[0-9]+]]
|
|
%alloc = call i8* @allocator(i32 20, %struct.__jmp_buf_tag* %arraydecay) #3
|
|
ret i8 *%alloc
|
|
}
|
|
|
|
; Tests if program does not crash when there's no setjmp function calls in the
|
|
; module.
|
|
@buffer = global [1 x %struct.__jmp_buf_tag] zeroinitializer, align 16
|
|
define void @longjmp_only() {
|
|
entry:
|
|
; CHECK: call void @emscripten_longjmp
|
|
call void @longjmp(%struct.__jmp_buf_tag* getelementptr inbounds ([1 x %struct.__jmp_buf_tag], [1 x %struct.__jmp_buf_tag]* @buffer, i32 0, i32 0), i32 1) #1
|
|
unreachable
|
|
}
|
|
|
|
; Tests if SSA rewrite works when a use and its def are within the same BB.
|
|
define void @ssa_rewite_in_same_bb() {
|
|
entry:
|
|
call void @foo()
|
|
br label %for.cond
|
|
|
|
for.cond: ; preds = %for.inc, %entry
|
|
; CHECK: %{{.*}} = phi i32 [ %var[[VARNO:.*]], %for.inc.split ]
|
|
%0 = phi i32 [ %var, %for.inc ], [ undef, %entry ]
|
|
%var = add i32 0, 0
|
|
br label %for.inc
|
|
|
|
for.inc: ; preds = %for.cond
|
|
%call5 = call i32 @setjmp(%struct.__jmp_buf_tag* undef) #0
|
|
br label %for.cond
|
|
|
|
; CHECK: for.inc.split:
|
|
; CHECK: %var[[VARNO]] = phi i32 [ %var, %for.inc ]
|
|
}
|
|
|
|
; Tests cases where longjmp function pointer is used in other ways than direct
|
|
; calls. longjmps should be replaced with
|
|
; (int(*)(jmp_buf*, int))emscripten_longjmp.
|
|
declare void @take_longjmp(void (%struct.__jmp_buf_tag*, i32)* %arg_ptr)
|
|
define void @indirect_longjmp() {
|
|
; CHECK-LABEL: @indirect_longjmp
|
|
entry:
|
|
%local_longjmp_ptr = alloca void (%struct.__jmp_buf_tag*, i32)*, align 4
|
|
%buf0 = alloca [1 x %struct.__jmp_buf_tag], align 16
|
|
%buf1 = alloca [1 x %struct.__jmp_buf_tag], align 16
|
|
|
|
; Store longjmp in a local variable, load it, and call it
|
|
store void (%struct.__jmp_buf_tag*, i32)* @longjmp, void (%struct.__jmp_buf_tag*, i32)** %local_longjmp_ptr, align 4
|
|
; CHECK: store void (%struct.__jmp_buf_tag*, i32)* bitcast (void (i32, i32)* @emscripten_longjmp to void (%struct.__jmp_buf_tag*, i32)*), void (%struct.__jmp_buf_tag*, i32)** %local_longjmp_ptr, align 4
|
|
%longjmp_from_local_ptr = load void (%struct.__jmp_buf_tag*, i32)*, void (%struct.__jmp_buf_tag*, i32)** %local_longjmp_ptr, align 4
|
|
%arraydecay = getelementptr inbounds [1 x %struct.__jmp_buf_tag], [1 x %struct.__jmp_buf_tag]* %buf0, i32 0, i32 0
|
|
call void %longjmp_from_local_ptr(%struct.__jmp_buf_tag* %arraydecay, i32 0)
|
|
|
|
; Load longjmp from a global variable and call it
|
|
%longjmp_from_global_ptr = load void (%struct.__jmp_buf_tag*, i32)*, void (%struct.__jmp_buf_tag*, i32)** @global_longjmp_ptr, align 4
|
|
%arraydecay1 = getelementptr inbounds [1 x %struct.__jmp_buf_tag], [1 x %struct.__jmp_buf_tag]* %buf1, i32 0, i32 0
|
|
call void %longjmp_from_global_ptr(%struct.__jmp_buf_tag* %arraydecay1, i32 0)
|
|
|
|
; Pass longjmp as a function argument. This is a call but longjmp is not a
|
|
; callee but an argument.
|
|
call void @take_longjmp(void (%struct.__jmp_buf_tag*, i32)* @longjmp)
|
|
; CHECK: call void @take_longjmp(void (%struct.__jmp_buf_tag*, i32)* bitcast (void (i32, i32)* @emscripten_longjmp to void (%struct.__jmp_buf_tag*, i32)*))
|
|
ret void
|
|
}
|
|
|
|
declare void @foo()
|
|
; Function Attrs: returns_twice
|
|
declare i32 @setjmp(%struct.__jmp_buf_tag*) #0
|
|
; Function Attrs: noreturn
|
|
declare void @longjmp(%struct.__jmp_buf_tag*, i32) #1
|
|
declare i32 @__gxx_personality_v0(...)
|
|
declare i8* @__cxa_begin_catch(i8*)
|
|
declare void @__cxa_end_catch()
|
|
declare i8* @malloc(i32)
|
|
declare void @free(i8*)
|
|
|
|
; JS glue functions and invoke wrappers declaration
|
|
; CHECK-DAG: declare i32 @getTempRet0()
|
|
; CHECK-DAG: declare void @setTempRet0(i32)
|
|
; CHECK-DAG: declare i32* @saveSetjmp(%struct.__jmp_buf_tag*, i32, i32*, i32)
|
|
; CHECK-DAG: declare i32 @testSetjmp(i32, i32*, i32)
|
|
; CHECK-DAG: declare void @emscripten_longjmp(i32, i32)
|
|
; CHECK-DAG: declare void @__invoke_void(void ()*)
|
|
|
|
attributes #0 = { returns_twice }
|
|
attributes #1 = { noreturn }
|
|
attributes #2 = { nounwind }
|
|
attributes #3 = { allocsize(0) }
|
|
; CHECK-DAG: attributes #{{[0-9]+}} = { nounwind "wasm-import-module"="env" "wasm-import-name"="getTempRet0" }
|
|
; CHECK-DAG: attributes #{{[0-9]+}} = { nounwind "wasm-import-module"="env" "wasm-import-name"="setTempRet0" }
|
|
; CHECK-DAG: attributes #{{[0-9]+}} = { "wasm-import-module"="env" "wasm-import-name"="__resumeException" }
|
|
; CHECK-DAG: attributes #{{[0-9]+}} = { "wasm-import-module"="env" "wasm-import-name"="llvm_eh_typeid_for" }
|
|
; CHECK-DAG: attributes #{{[0-9]+}} = { "wasm-import-module"="env" "wasm-import-name"="__invoke_void" }
|
|
; CHECK-DAG: attributes #{{[0-9]+}} = { "wasm-import-module"="env" "wasm-import-name"="__cxa_find_matching_catch_3" }
|
|
; CHECK-DAG: attributes #{{[0-9]+}} = { "wasm-import-module"="env" "wasm-import-name"="saveSetjmp" }
|
|
; CHECK-DAG: attributes #{{[0-9]+}} = { "wasm-import-module"="env" "wasm-import-name"="testSetjmp" }
|
|
; CHECK-DAG: attributes #{{[0-9]+}} = { "wasm-import-module"="env" "wasm-import-name"="emscripten_longjmp" }
|
|
; CHECK-DAG: attributes #{{[0-9]+}} = { "wasm-import-module"="env" "wasm-import-name"="__invoke_i8*_i32_%struct.__jmp_buf_tag*" }
|
|
; CHECK-DAG: attributes #[[ALLOCSIZE_ATTR]] = { allocsize(1) }
|
|
|
|
!llvm.dbg.cu = !{!2}
|
|
!llvm.module.flags = !{!0}
|
|
|
|
!0 = !{i32 2, !"Debug Info Version", i32 3}
|
|
!1 = !DIFile(filename: "lower-em-sjlj.c", directory: "test")
|
|
!2 = distinct !DICompileUnit(language: DW_LANG_C99, file: !1)
|
|
!3 = distinct !DISubprogram(name: "setjmp_debug_info", unit:!2, file: !1, line: 1)
|
|
!4 = !DILocation(line:2, scope: !3)
|
|
!5 = !DILocation(line:3, scope: !3)
|
|
!6 = !DILocation(line:4, scope: !3)
|
|
!7 = !DILocation(line:5, scope: !3)
|
|
!8 = !DILocation(line:6, scope: !3)
|